Всё о КВЕСТАХ

Код: Выделить всё

//#TQ_PROJECT
/*
  Пример многострочного комментария.

  Пример простейшей программы квеста.
  Автор: haM3r
  E-mail: bvlad36@bk.ru
*/

// Пример подключения дополнительной библиотеки.
// Проект можно разбивать отдельные на файлы.
 #include "scene_1.tq";
 #include "scene_2.tq";
 #include "scene_3.tq";


/*
  Пример работы с #define.
  #define - автозамена текста. Довольно полезная вещь.
  Можно сказать  #define "btn", "button"; и использовать
  во всей программе заместо button - btn.
*/
 #define "btn", "button";



//-----------------------------------------------
/*
  Пример локации.
  Локация должна начинаться со слова location или room
  и заканчиваться end.
  <main> - указывает на то, что с этой локации начинает
  работать программа.
*/
location [first_location] <main>

   // Устанавливаем цвет текста.
   textcolor 5;

   // Проиграть звуковой wav файл.
   play "sound.wav";

   // Вывод сообщения на экран.
   print "Первая локация\n";

      button room_1, "@Wкомната-1";
      button room_2, "@Bкомната-2";
      button room_3, "@Rкомната-3";
end;

//-----------------------------------------------

room [room_1]
   // Проигрывание звукового сигнала.
   beep;

   print "В комнате 1 вас убили!\n",
         "Какая досада!\n",
         "Попробуйте ещё раз.\n";

   // Заснуть на 1 секунду.
   sleep 1000;

   // Выход из программы.
   exit;
end;


procedure getkey
   print "Press any key...";

   // Считывание клавиши.
   key = readkey;

   print "key = ", key;
end;

room [room_2]
   // Отчистка экрана.
   cls;

   // Вызов процедуры.
   call getkey;

   // Сохранение состояния программы.
   save;

   btn first_location, "Назад";
end;


room [room_3]
   a = 10;
   b = "test";
   print "This is" + b + "\n";


   :label_1
   // Пример цикла.   
   while (a > 0)
   {
      print a, "\n"

      // Пример условного оператора.
      if (a == 3)
      {
         print "That's All!\n";
         break;
      }
      a = a - 1;
   }

   if (a > 0)
      goto label_1;

   exit;
end;